Re: Inclinazione dei raggi solari

From: Daniele Fua <daniele.fua_at_unimib.it>
Date: Tue, 05 Dec 2006 15:19:52 GMT

torcH wrote:
> Salve a tutti, spero di non essere eccessivamente OT.
>
> Qualcun di voi saprebbe indicarmi un software per calcolare la diversa
> inclinazione dei raggi solari, alle varie latitudini, nell'arco dell'anno?
> O magari esistono delle tabelle precompilate da consultare?
>
> Ringrazio e saluto,
> torcH

Non sei eccessivamente OT anche se su astronomia ti avrebbero risposto
meglio e prima.
Il dato che chiedi e' abbastanza semplice e non serve un software
complicato; se sai programmare in un qualsiasi linguaggio ti puoi
calcolare le formule che sono, essenzialmente, due.
1) Una formula approssimata (ma molto piu' precisa di quanto ti serva)
per calcolare la declinazione del sole (decl) in funzione del giorno
dell'anno.
2) una formula trigonometrica per calcolare l'angolo zenitale del sole
(sza) in funzione della declinazione solare, della latitudine e
longitudine del punto e dell'ora GMT. L'angolo zenitale e' l'angolo
rispetto allo zenit.

C'e' un'altra correzione importante ("equazione del tempo", eqt) che
deve essere calcolata ma non credo che valga la pena parlarne qui; tanto
e' inclusa nel programmino che segue.

Ecco la lista di una subroutine in FORTRAN che uso normalmente e funziona.

c=================================================================

c
c
        subroutine calcsza(dn,tgmt,alat,along,sza)
c
c Calculates Solar Zenith Angle as a function of latitude,
c longitude, time of the day, day of the year.
c
c eqt - equation of time
c dn - day number (0 for January 1)
c tgmt - time GMT
c decl - solar declination
c along - longitude in deg (positive E of Greenwich, negative W)
c alat - latitude (negative for S hemisphere)
c thn - angular day (rad)
c th - local hour angle
c sza - solar zenith angle
c
c Expressions for SZA derived from Spencer, J.W., Fourier series
c representation of the position of the sun, Search, 2, 172, 1971
c
c
        real*8 eqt1,eqt2,eqt3,eqt4,eqt5,dec1,dec2,dec3,dec4,dec5
        real*8 dec6,dec7,decl,eqt,thn,th,alat,along,sza
        real*8 rr1,rr2,rr3,rr4,rr5,dn,tgmt,a,b,pi,a2,b2,a3,b3
        real*8 thn2,thn3,csza,altr,algr,cf
c
        data eqt1,eqt2,eqt3/0.000075,0.001868,-0.032077/
        data eqt4,eqt5/-0.014615,-0.040849/
        data dec1,dec2,dec3/0.006918,-0.399912,0.070257/
        data dec4,dec5,dec6/-0.006758,0.000907,-0.002697/
        data dec7/0.001480/
        data pi/3.14159265/
c
        cf=pi/180.0
        altr=cf*alat
        algr=cf*along
        thn=2.0*pi*dn/365.0
        thn2=2.0*thn
        thn3=3.0*thn
        a=cos(thn)
        b=sin(thn)
        a2=cos(thn2)
        b2=sin(thn2)
        a3=cos(thn3)
        b3=sin(thn3)
c
        eqt=eqt1+a*eqt2+b*eqt3+a2*eqt4+b2*eqt5
        decl=dec1+a*dec2+b*dec3+a2*dec4+b2*dec5+a3*dec6+b3*dec7
        th=pi*(tgmt/12.0-1.0+along/180.0)+eqt
        csza=sin(decl)*sin(altr)+cos(decl)*cos(altr)*cos(th)
        sza=acos(csza)/cf
c
        return
        end
c=============================================================


Spero di non essere andato io OT!

Daniele Fua
Uni.Roma1
Received on Tue Dec 05 2006 - 16:19:52 CET